

Задание 2. Разработать распознаватели для КС-грамматик
Индивидуальные варианты к заданию 2
1. Формальный язык Even очень прост: он содержит все строки, содержащие все четные числа, содержащие четные цифры из s. Пустая строка также принадлежит языку Even . Описать КС-грамматику и распознаватель на Прологе
2. Формальный язык a n b 2 m c 2 m d n содержит все строки в следующей форме: повторение символов a, за которыми  следует повторение символов b, затем повторение символов  c и повторение символов d, так, что длины блоков a и d одинаковы, а длины блоков b и c тоже равны, но в 2 раза длиннее рассмотренных ранее. Например, цепочки abbccd и aabbbbccccdd принадлежат описываемому языку . Описать НС-грамматику и распознаватель на Прологе.
3.  Язык логических формул состоит из символов p , q  и  r и операций  отрицание (not), дизъюнкция (dis), конъюнкция (kon), импликация (impl). Описать КС-грамматику формул этого языка и распознаватель на Прологе
4. Описать язык арифметических выражений: операнды – числа (с) и переменные 9i0, 4 арифметические операции, открывающая и закрывающая круглые скобки. Описать КС-грамматику и распознаватель на Прологе
5. Описать КС-грамматику предложения, состоящего из групп  подлежащего, сказуемого, предлога и т.д. для следующих примеров:
     John makes good coffee for his friends.
     Starkid paints his spaceship every year.
     I usually get up at seven o’clock.
     First I bought new space shoes.
     The sport shop is opposite the hotel.
6. Описать КС-грамматику оператора for
7. Описать КС-грамматику оператора while
8. Описать КС-грамматику оператора do…while
9. Описать КС=грамматику функции
10. Описать КС-грамматику оператора if
11. Описать КС-грамматику оператора switch
В вариантах 6-11 внутри цикла или в операциях развилки несколько операторов присваивания
12. Описать КС-грамматику операторов ввода-вывода

Грамматики
Контекстно – свободные (КС) грамматики
Пролог используется для многих целей, в частности, для компьютерной. 
КС грамматика – специальное обозначение  для определения грамматики. Определим, что такое грамматика.. Основная идея КС-грамматики описывает структуру всех естественных языков (например, английского, французского и русского) естественным образом. 
Итак, КС-грамматика – конечный набор правил, описывающих, что   определенный набор предложений грамматически (то есть синтаксически) верен и какова их структура. Вот пример КС-грамматики небольшого фрагмента английского языка: 
	s  ->  np  vp 

	np  ->  det  n 

	vp  ->  v  np 

	vp  ->  v 

	det  -> a 

	det  -> the 

	n  -> woman 

	n  -> man 

Из чего состоит эта небольшая грамматика? Она содержит 3 типа элементов. Первый это  -> , который отделяет левую часть правила от правой. s , np, vp,n,v,det  это нетерминальные символы. Каждый из них имеет традиционный смысл в лингвистике: s - предложение, np – группа существительного, vp – группа глагола, v – глагол, det- артикль, то есть все это грамматические категории. a, the, woman, man , shoots –терминальные символы или алфавит или лексические элементы.. Будем называть их словами. 
Эта грамматика содержит 9 КС-правил. Каждое правило содержит один нетерминал, знак ->  и конечную последовательность терминалов и нетерминалов. Каков смысл этих правил? Они объясняют, как можно построить различные грамматические категории. -> читается: «может содержать» . Например, 1 правило говорит, что предложение содержит группу существительного и группу глагола. 3 правило говорит о том, что группа глагола содержит глагол, за которым следует группа существительного, в то время, как 4 правило говорит, что есть другой способ представления группы глагола – только глагол. Последние пять правил говорят, что a и the - артикли, что man и woman – существительные и что shoots - глагол. 
Рассмотрим строку слов a woman shoots a man . Является ли эта строка грамматически правильной в соответствии с нашей грамматикой? И если да, какую структуру она имеет? Следующее дерево отвечает на оба вопроса: 


Узел  s имеет двух потомков – np и vp. Заметим, что эта часть диаграммы согласуется с правилом 1. Можно видеть, что каждая часть дерева согласуется с одним из правил. Заметим, что терминальные узлы располагаются в листьях дерева. 
Такое дерево называется синтаксическим деревом. Оно важно, так как дает двоякую информацию, Во-первых, информацию о предложении, во-вторых, информацию о структуре. Такое дерево можно выстроить для любого правильного предложения языка. 
С другой стороны, если нельзя построить такое дерево, то предложение грамматически неверно. Например, предложение woman a woman man a shoots грамматически неверно. Язык, генерируемый грамматикой, содержит все правильные предложения. Например, a woman shoots a man также принадлежит языку, а также a man shoots the woman . КС –распознаватель – это программа, которая определяет, принадлежит ли предложение языку. Часто мы не просто интересуемся, принадлежит ли строка грамматике или нет, мы также хотим знать, какова структура предложения. Такая информация важна, если предложение используется в некоторых приложениях. КС-синтаксический анализатор не просто говорит “Да, предложение верно” or “Нет, оно неверно”, но он строит дерево. 
КС-распознаватель, использующий предикат append
Как работать с КС грамматикой в Прологе? Как написать распознаватель для КС-грамматики? Сначала рассмотрим простейший распознаватель, а затем покажем, как можно записать более сложные распознаватели с помощью разностных списков. 
Итак, для заданной КС-грамматики определим распознаватель на Прологе. Действительно, Пролог предлагает очень прямой ответ на вопрос можно просто записать предикаты, соответствующие правилам грамматики. То есть, мы просто должны превратить грамматику в правила Пролога. 
Вот простой способ сделать это. Используем списки для представления предложений. Например, используем список [a, woman, shoots, a, man]. Затем -> в КС-грамматике означает «состоит из», и это также моделируется в  виде списко. Например, правило s  ->  np  vp можно рассматриваться следующим образом: список s есть результат объединения списков np И vp. Как мы знаем, для объединения списков надо использовать предикат append. Правила с отдельными словами преобразуются еще проще.  Например, n  -> woman говорит о том, что список [woman] является списком n. 
Итак, мы получим: 
s(Z):- np(X), vp(Y), append(X,Y,Z).
np(Z):- det(X), n(Y), append(X,Y,Z).
vp(Z):- v(X), np(Y), append(X,Y,Z).
vp(Z):- v(Z).
det([the]).
det([a]).
n([woman]).
n([man]).
v([shoots]).
Чтобы использовать эту программу как распознаватель, просто сформулируем очевидные запросы. Например: 
?- s([a,woman,shoots,a,man]).
yes
Можно также выдать все предложения, генерируемые грамматикой (для нашей грамматики их 20). Вот первые 5: 
?- s(X).
X = [the,woman,shoots,the,woman] ;
X = [the,woman,shoots,the,man] ;
X = [the,woman,shoots,a,woman] ;
X = [the,woman,shoots,a,man] ;
X = [the,woman,shoots]
Можно также спросить о других грамматических категориях. Например: 
?- np([a,woman]).
yes
Можно сгенерировать группы существительного. 
?- np(X).
Итак, получили простой способ понимания программы, которая соответствует нашей КС-грамматике. 
Однако есть проблема: программа не использует входное предложение для направления поиска. Если выполнить трассировку запроса s([a,man,shoots]), то можно увидеть, что программа выбирает группу существительного и группу глагола и только после этого проверяет, можно ли их объединить в предложение [a,man,shoots] .Например, Пролог найдет, что [the,woman] 0 группа существительного и [shoots,the,woman] - группа глагола и затем проверит, что их объединение дает [a,man,shoots], что конечно неверно, Поэтому произойдет откат, и будет попытка объединить группу существительного [the,woman] группу глагола [shoots,the,man], последняя попытка – объединить группу существительного  [a,man] и группу глагола [shoots]. Проблема в том, что цели np(X) и vp(Y)вызываются с неинициализированными переменными в к4ачестве аргументов 
Поэтому изменим правила так, что append становится первой целью: 

s(Z):- append(X,Y,Z), np(X), vp(Y).
np(Z):- append(X,Y,Z), det(X), n(Y).
vp(Z):-  append(X,Y,Z), v(X), np(Y).
vp(Z):-  v(Z).
det([the]).
det([a]).
n([woman]).
n([man]).
v([shoots]).

Итак, мы вначале выполняем append, чтобы разделить входной список. Это приводит к инициализации переменных X и Y , так что остальные цели вызываются с инициализированными аргументами Однако, эта программа все еще не очень привлекательна
. 
КС-распознаватель, использующий списки различий
Основная идея, лежащая в основе списков различий, - представить информацию о грамматических категориях не как один список, но как отличие между двумя списками. Например, вместо того, чтобы представить a woman shoots a man как [a,woman,shoots,a,man] можно представить его как два списка [a,woman,shoots,a,man] [].
Первый можно рассматривать как входной список, а второй – как выходной список (или список, который останется, если мы используем первый). Для нашего примера списки различий [a,woman,shoots,a,man] [] представляют предложение a woman shoots a man, так как можно сказать: если использовать все слова левого списка, то останется пустой список, а это значит, имеем заданное предложение. То есть искомое предложение есть различие между содержимым этих двух списков. 
Это все, что нужно знать о списках различия, чтобы переписать распознаватель. Тогда следующий распознаватель:
 
s(X,Z):- np(X,Y), vp(Y,Z).
np(X,Z):- det(X,Y), n(Y,Z).
vp(X,Z):-  v(X,Y), np(Y,Z).
vp(X,Z):-  v(X,Z).
det([the|W],W).
det([a|W],W).
n([woman|W],W).
n([man|W],W).
v([shoots|W],W).

Для слов имеем факты вида n([man|W],W)., что означает, что man – это разность между [man|W] и W . Сначала возможно этот код сложнее понять, но зато мы избавились от предиката append. 
Как можно использовать этот распознаватель? Запрос: 
?- s([a,woman,shoots,a,man],[]). дает результат
yes
Подобным образом, чтобы сгенерировать предложения грамматики, выполним запрос 
?- s(X,[]). Это означает, что мы хотим увидеть списки  X , такие, что за пределами них ничего не останется.
Запросы для других грамматических категорий также работают подобным образом. 
Например, чтобы вывести, является ли a woman группой существительного, нужно запросить: 
?- np([a,woman],[]).
Чтобы сгенерировать все группы существительного, нужно запросить: 
?- np(X,[]).
Еще один способ представления КС-грамматики в Прологе покажем на примере
правило("выражение", ["слагаемое"]).
правило("выражение", ["слагаемое","аддзнак","выражение"]).
правило("слагаемое", ["множитель"]).
правило("слагаемое", ["множитель","мультзнак","слагаемое"]).
правило("множитель", ["число"]).
правило("множитель", ["переменная"]).

термСимвол("аддзнак", "+").
термСимвол("аддзнак", "-").
термСимвол("мультзнак", "*").
термСимвол("мультзнак", "/").
термСимвол("число", "3").
термСимвол("переменная", "x").
 

генератор(НетермСимвол, Выражение):-
    правило(НетермСимвол, Список),
    ген_выражений(Список, Выражение).

ген_выражений([], []).
ген_выражений([НетермСимвол|Ост], [ТермСимвол|Слова]):-
      термСимвол(НетермСимвол, ТермСимвол),
        ген_выражений(Ост, Слова).
ген_выражений([НетермСимвол|Ост], Слова):-
    правило(НетермСимвол, Символы),
    appd(Символы, Ост, Список),
    ген_выражений(Список, Слова).

appd([A|L1],L2,[A|L]):- appd(L1,L2,L).
appd([],L,L).

Если задать запрос:
генератор(X,["x","+","3"])., то получим ответ.

X = "выражение" ;

Если выполнить запрос генератор("выражение",X)., то получим ответы
X = ["3"] 
X = ["x"] ;
X = ["3", "*", "3"] ;
X = ["3", "*", "x"] ;
X = ["3", "*", "3", "*", "3"] ;
X = ["3", "*", "3", "*", "x"] ;
X = ["3", "*", "3", "*", "3", "*", "3"] ;
X = ["3", "*", "3", "*", "3", "*", "x"] ;
X = ["3", "*", "3", "*", "3", "*", "3", "*", "3"] ;
X = ["3", "*", "3", "*", "3", "*", "3", "*", "x"]
и так далее

